一、VLOOKUP函数的定义

1、纵向查找函数
VLOOKUP函数是Excel中的一个纵向查找函数，它与LOOKUP函数和baiHLOOKUP函数属于一类函数，在工作中都有广泛应用，例如可以用来核对数据，多个表格之间快速导入数据等函数功能。

2、按列查找
功能是按列查找，最终返回该列所需查询列序所对应的值；与之对应的HLOOKUP是按行查找的。

二、参数说明

1、第一列中进行查找的数值
Lookup_value为需要在数据表第一列中进行查找的数值。Lookup_value 可以为数值、引用或文本字符串。当vlookup函数第一参数省略查找值时，表示用0查找。

2、查找数据的数据表
（1）、Table_array为需要在其中查找数据的数据表。使用对区域或区域名称的引用。col_index_num为table_array中查找数据的数据列序号。col_index_num 为 1 时，返回 table_array 第一列的数值，col_index_num 为 2 时，返回 table_array 第二列的数值，以此类推。

（2）、如果 col_index_num 小于1，函数 VLOOKUP 返回错误值 #VALUE!；如果 col_index_num 大于 table_array 的列数，函数 VLOOKUP 返回错误值#REF!。

3、Range_lookup
（1）、Range_lookup为一逻辑值，指明函数 VLOOKUP 查找时是精确匹配，还是近似匹配。如果为FALSE或0 ，则返回精确匹配，如果找不到，则返回错误值 #N/A。

（2）、如果 range_lookup 为TRUE或1，函数 VLOOKUP 将查找近似匹配值，也就是说，如果找不到精确匹配值，则返回小于 lookup_value 的最大数值。如果range_lookup 省略，则默认为近似匹配。

 

一 、常规查询

1、姓名查询对应的职务
（1）、如图，需要从B-E的数据表中，根据H3单元格的姓名查询对应的职务。

（2）、公式为：=VLOOKUP(H3,C:E,3,0)

2、提示
VLOOKUP函数第三参数中的列号，不能理解为工作表中实际的列号，而是指定要返回查询区域中第几列的值。

二、带通配符的查询

1、根据姓氏查询对应的姓名和部门
（1）、如图，需要从B-E的数据表中，根据H3单元格的姓氏，查询对应的姓名和部门。

（2）、公式为：=VLOOKUP($H3&"*",$C:$E,COLUMN(A1),0)

2、提示
通配符“*”表示任意多个字符，VLOOKUP函数第一参数使用$H3&"*"，即在C列中查询以H2单元格内容开头的内容，并返回对应列的信息。

三、近似查询

1、D列成绩对应的评议结果
（1）、如图，需要根据H-I的对照表，判断D列成绩对应的评议结果。

（2）、公式为：=VLOOKUP(D2,H:I,2)

2、提示
（1）、VLOOKUP函数第四参数被省略，在近似匹配模式下返回查询值的精确匹配值或近似匹配值。

（2）、如果找不到精确匹配值，则返回小于查询值的最大值。

（3）、使用近似匹配时，查询区域的首列必须按升序排序，否则无法得到正确的结果。

四、逆向查询

1、H3单元格的部门查询对应的姓名
（1）、如图，需要从B~E的数据表中，根据H3单元格的部门，查询对应的姓名。

（2）、公式为：=VLOOKUP(H3,CHOOSE({1,2},D2:D11,C2:C11),2,0)

2、提示
（1）、VLOOKUP函数的查询值要求必须位于查询区域中的首列，如果被查找值不在数据表的首列时，需要先将目标数据进行特殊的转换。

（2）、CHOOSE函数第一参数使用常量数组{1,2}，将查询值所在的D2:D11和返回值所在的C2:C11整合成一个新的两列多行的内存数组。

（3）、生成的内存数组符合VLOOKUP函数的查询值必须处于数据区域中首列的要求。VLOOKUP函数以职务做查询条件，在内存数组中查询并返回对应的姓名信息，从而实现了逆向查询的目的。

五、多条件查询

1、H3单元格的部门和I3单元格的职务查询对应的姓名
（1）、如图，需要从B-E的数据表中，根据H3单元格的部门和I3单元格的职务，查询对应的姓名。

（2）、J3单元格公式为：=VLOOKUP(H3&I3,IF({1,0},D2:D11&E2:E11,C2:C11),2,)

2、提示
（1）、使用连接符“&”将部门和职务合并成新的字符串，以此作为VLOOKUP函数的查询条件。

（2）、IF部分，先将D列的部门和E列的职务进行连接，再使用IF({1,0}的方式，构造出部门职务在前、姓名在后的内存数组。

（3）、VLOOKUP函数在IF函数构造出的内存数组首列中查询部门职务字符串的位置，返回对应的姓名。

（4）、数组公式，不要忘了按<Ctrl+Shift+Enter>组合键。

六、一对多查询

1、3单元格的职务查询对应的多个姓名
（1）、如图，需要从B-E的数据表中，根据H3单元格的职务，查询对应的多个姓名。

（2）、首先在A2单元格输入以下公式，向下复制：=(E2=$H$3)+A1

（3）、然后在I3单元格输入以下公式，向下复制：=IFERROR(VLOOKUP(ROW(A1),A:C,3,0),"")

2、提示
（1）、C列的职务每重复出现一次，A列的序号增加1。

（2）、VLOOKUP函数使用1至N的递增序列作为查询值，使用A:C列作为查询区域，以精确匹配的方式返回与之相对应的B列的姓名。注意查找区域必须由辅助列A列开始。

（3）、最后将辅助列字体设置为白色或进行隐藏即可。

七、按指定次数重复数据

1、C列指定的次数重复显示B列的内容
（1）、如图，需要根据C列指定的次数，重复显示B列的内容。

（2）、首先在A2单元格输入以下公式，向下复制：=A1+C2

2、输入公式
然后在E2单元格输入以下公式，向下复制：=IFERROR(VLOOKUP(ROW(A1),A:B,2,0),E3)&""